커스텀 쉐이더

Shader "Sample Shader/Gamma Space - Normal - AlphaBlend"
{
  Properties
  {
    _Color ("2X Color (RGBA Mul)", Color) = (0.5, 0.5, 0.5, 1.0)
    _MainTex ("Main Texture (RGBA)", 2D) = "white" {}
  }

  SubShader
  {
    Tags { "RenderType" = "Transparent" "Queue" = "Transparent" "PreviewType" = "Plane" }
    Blend SrcAlpha OneMinusSrcAlpha
    LOD 200

    Pass
    {
      Tags { "LightMode" = "ForwardBase" }
      ZWrite Off

      CGPROGRAM
      #pragma vertex vert
      #pragma fragment frag

      #include "UnityCG.cginc"

      struct appdata
      {
        float4 vertex : POSITION;
        float2 uv : TEXCOORD0;
      };

      struct v2f
      {
        float2 uv : TEXCOORD0;
        float4 vertex : SV_POSITION;        
      };

      sampler2D _MainTex;
      float4 _MainTex_ST;
      half4 _Color;

      v2f vert (appdata v)
      {
        v2f o;
        o.vertex = UnityObjectToClipPos(v.vertex);
        o.uv = TRANSFORM_TEX(v.uv, _MainTex);
        return o;
      }

      fixed4 frag (v2f i) : SV_Target
      {
        fixed4 col = tex2D(_MainTex, i.uv);

        col.rgb *= _Color.rgb * 2.0f;
        col.a *= _Color.a;

        return col;
      }
      ENDCG
    }

    Pass
    {
      Tags { "LightMode" = "ShadowCaster" }
      ZWrite On

      CGPROGRAM
      #pragma vertex vert
      #pragma fragment frag
      #pragma multi_compile_shadowcaster
      #include "UnityCG.cginc"

      struct appdata
      {
        float4 vertex : POSITION;
        float2 uv : TEXCOORD0;
      };

      struct v2f
      {
        float2 uv : TEXCOORD0;
        V2F_SHADOW_CASTER;
      };

      sampler2D _MainTex;
      float4 _MainTex_ST;
      half4 _Color;

      v2f vert(appdata_base v)
      {
        v2f o;
        TRANSFER_SHADOW_CASTER_NORMALOFFSET(o)
        o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
        return o;
      }

      float4 frag(v2f i) : SV_Target
      {
        fixed4 col = tex2D(_MainTex, i.uv);
        col.a *= _Color.a;

        if(col.a < 0.05f)
        {
          discard;
        }
        SHADOW_CASTER_FRAGMENT(i)
      }
      ENDCG
    }
  }
}

      ...
      fixed4 frag (v2f i) : SV_Target
      {
        fixed4 col = tex2D(_MainTex, i.uv);

        col.rgb *= _Color.rgb * 4.595f;
        col.rgb = pow(col.rgb, 2.2f);
        col.a *= _Color.a;

        return col;
      }
      ...

  ...
  SubShader
  {
    Tags { "RenderType" = "Transparent" "Queue" = "Transparent" "PreviewType" = "Plane" }

    // --- 블렌딩 종류에 따라 선택하여 작성 ---
    Blend One One // Additive
    Blend OneMinusDstColor One // Soft Additive
    Blend DstColor SrcColor // Multiplicative

    LOD 200

    Pass
    {
      // --- 패스 지정 코드 삭제 ---
      // Tags { "LightMode" = "ForwardBase" } : 삭제
      ZWrite Off

      CGPROGRAM
      ...
      fixed4 frag (v2f i) : SV_Target
      {
        fixed4 col = tex2D(_MainTex, i.uv);

        col.rgb *= _Color.rgb * 2.0f;
        col.a *= _Color.a;

        // --- Additive 또는 Soft Additive ---
        col.rgb *= col.a;
        col.a = 1.0f;
        // ---------------------------------

        // --- Multiplicative ---
        col.rgb = col.rgb * (col.a) + float4(0.5f, 0.5f, 0.5f, 1.0f) * (1.0f - col.a);
        col.a = 1.0f;
        // ----------------------

        return col;
      }
      ENDCG
    }
    // 그림자 생성 패스 코드 삭제
  }
}

Shader "Sample Shader/Gamma Space - Clipped - AlphaBlend"
{
  Properties
  {
    _Color ("2X Color (RGBA Mul)", Color) = (0.5, 0.5, 0.5, 1.0)
    _MainTex ("Main Texture (RGBA)", 2D) = "white" {}

    // --- 클리핑 프로퍼티 ---
    _MaskTex ("Mask Texture (A)", 2D) = "white" {}
    _MaskScreenSpaceOffset ("Mask Screen Space Offset (XY_Scale)", Vector) = (0, 0, 0, 1)
  }

  SubShader
  {
    Tags { "RenderType" = "Transparent" "Queue" = "Transparent" "PreviewType" = "Plane" }
    Blend SrcAlpha OneMinusSrcAlpha
    ZWrite Off
    LOD 200

    Pass
    {
      CGPROGRAM
      #pragma vertex vert
      #pragma fragment frag

      #include "UnityCG.cginc"

      struct appdata
      {
        float4 vertex : POSITION;
        float2 uv : TEXCOORD0;
      };
      struct v2f
      {
        float2 uv : TEXCOORD0;
        float4 vertex : SV_POSITION;

        // --- 클리핑 연산을 위한 Screen Position ---
        float4 screenPos : TEXCOORD1;
      };

      sampler2D _MainTex;
      float4 _MainTex_ST;
      half4 _Color;

      // --- 클리핑용 프로퍼티 변수 ---
      sampler2D _MaskTex;
      float4 _MaskScreenSpaceOffset;

      v2f vert (appdata v)
      {
        v2f o;
        o.vertex = UnityObjectToClipPos(v.vertex);
        o.uv = TRANSFORM_TEX(v.uv, _MainTex);

        // --- 클리핑용 Screen Position 계산 ---
        o.screenPos = ComputeScreenPos(o.vertex);

        return o;
      }

      
      fixed4 frag (v2f i) : SV_Target
      {
        fixed4 col = tex2D(_MainTex, i.uv);

        col.rgb *= _Color.rgb * 2.0f;
        col.a *= _Color.a;

        // --- 클리핑 마스크에 의한 알파 채널 연산 ---
        float2 screenUV = i.screenPos.xy / max(i.screenPos.w, 0.0001f);
        screenUV -= float2(0.5f, 0.5f);
        screenUV.x *= _MaskScreenSpaceOffset.z;
        screenUV.y *= _MaskScreenSpaceOffset.w;
        screenUV.x += _MaskScreenSpaceOffset.x * _MaskScreenSpaceOffset.z;
        screenUV.y += _MaskScreenSpaceOffset.y * _MaskScreenSpaceOffset.w;
        screenUV += float2(0.5f, 0.5f);
        col.a *= tex2D(_MaskTex, screenUV).r;

        return col;
      }
      ENDCG
    }
  }
}

Shader "Shader Example/Gamma Space - Normal - AlphaBlend (Keyword)"
{
  Properties
  {
    _Color ("2X Color (RGBA Mul)", Color) = (0.5, 0.5, 0.5, 1.0)
    _MainTex ("Main Texture (RGBA)", 2D) = "white" {}
  }

  SubShader
  {
    Tags { "RenderType" = "Transparent" "Queue" = "Transparent" "PreviewType" = "Plane" }
    Blend SrcAlpha OneMinusSrcAlpha
    LOD 200

    Pass
    {
      ZWrite Off
      CGPROGRAM
      #pragma vertex vert
      #pragma fragment frag

      #pragma multi_compile __ SPECIAL_COLOR

      #include "UnityCG.cginc"

      struct appdata
      {
        float4 vertex : POSITION;
        float2 uv : TEXCOORD0;
      };

      struct v2f
      {
        float2 uv : TEXCOORD0;
        float4 vertex : SV_POSITION;        
      };

      sampler2D _MainTex;
      float4 _MainTex_ST;
      half4 _Color;

      v2f vert (appdata v)
      {
        v2f o;
        o.vertex = UnityObjectToClipPos(v.vertex);
        o.uv = TRANSFORM_TEX(v.uv, _MainTex);
        return o;
      }

      fixed4 frag (v2f i) : SV_Target
      {
        fixed4 col = tex2D(_MainTex, i.uv);

        col.rgb *= _Color.rgb * 2.0f;
        col.a *= _Color.a;

        #ifdef SPECIAL_COLOR
        col.rgb *= fixed3(0.0f, 1.0f, 0.0f);
        #endif

        return col;
      }
      ENDCG
    }
  }
}